Problem II 4.2-type problem.  
Verify that the curve C is an integral curve of V, and derive a formula for infinitely many integral surfaces of V containing C.

V = (x, -y, 0), C: x = t, y = -1/t, z = 0 for all t > 0.

Answer: The surface with equation
F(xy, z) = 0 
is an integral surface for any smooth function F:R^2 -> R that satisfies F(-1,0) = 0.

I will show a “model solution” in this notebook.  I will also illustrate this result, showing the surfaces obtained by a “standard” choice of F.

Solution:
Two Functionally Independent First Integrals (FIFIs) for V are

u1[x_,y_,z_] := x y
u2[x_, y_, z_] := z

The hardest part of the problem is determining these 2 FIFIs and verifying that they are indeed functionally independent by computing the cross product of the gradients.

To show that C is an integral curve, compute 
U1(t) = u1(t, -1/t, 0) = (t)(-1/t) = -1 (for all t > 0) and
U2(t) = u2(t, -1/t, 0) =  0 (for all t > 0)

Since U1(t) and U2(t) are constant functions, the curve C is an integral curve of V.

Any smooth function F:R^2 → R will give a first integral F(xy, z) of V by Theorem 3.1.  This integral surface will contain C if and only if F(-1, 0) = 0, as shown in the proof of Theorem 4.3.
(End of the “model solution”.)

Now lets illustrate this result with a one-parameter family of functions F that satisfy F(-1, 0) = 0,  out of the unfathomably largely infinitely many such functions.

Here’s a tangent for you:  If we assume the continuum hypothesis, the cardinality of the set of functions F defined below is Aleph-1.   I don’t know set theory very well, but I think the cardinality of all functions F:R^2 → R that satisfy F(-1,0) = 0 is Aleph-2.  (That’s what I mean by unfathomably largely infinitely many such functions.)

My choice for a function F:R^2 → R that satisfies F(c1, c2) = 0 has a parameter θ.  So I actually define a function F:R^5 -> R, with c1, c2, and θ as the last three arguments of the function.  The set F(u1, u2, c1, c2, θ) = 0 is a line in through the point (c1, c2) that is perpendicular to the vector (cos(θ), sin(θ)).

F[u1_, u2_,c1_, c2_,θ_] := (u1-c1)Cos[θ] + (u2-c2)Sin[θ]

θ =π/6;
{c1, c2} = {-1, 0};
ContourPlot[F[u1, u2, c1, c2, θ]==0, {u1, -3,3}, {u2, -3,3}, Epilog ->{Arrow[{{c1,c2}, {c1,c2} + {Cos[θ], Sin[θ]}}],Point[{c1, c2}]}, FrameLabel ->{"(Subscript[u, 1])", "(Subscript[u, 2])"}, RotateLabel->False]

Now we plot the family of integral surfaces that go through C: x = t, y = -1/t, z = 0,
depending on the parameter θ. We have already determined that c1 = -1 and c2 = 0.
You must first run the cells where u1, u2, and F are defined, before running this cell.  I like to select all (Ctrl A) and run (Shift-ENTER, or bottom-right ENTER on some keyboards).

You can use the slider to change θ.
Clicking the + to the right of the slider allows you to see the value of θ and also animate the figure!

Manipulate[
L = 3;  (* -L ≤ x,y ≤ L *)
H  = 2; (* -H ≤ z ≤ H *)
c1 = -1;
c2 = 0;
integralCurve = Graphics3D[Tube[Table[{t, -1/t, 0}, {t,1/L, L, 1/(5L)}], .07] ];
integralSurface = ContourPlot3D[F[u1[x,y,z], u2[x,y,z], c1, c2, θ] == 0, {x, -L,L}, {y, -L, L}, {z, -H,H}, Mesh -> False];
Show[integralSurface, integralCurve, AxesLabel ->{"x", "y", "z"}, BoxRatios -> Automatic]
, {{θ, 2.2}, 0, π}]

Now do the same thing for the integral curve C: x = 0, y = -t, z = 0, t > 0.
In this case, c1 = u1(0,-t, 0) = 0, and c2 = u2(0, -t, 0) = 0.

Manipulate[
L = 3;  (* -L ≤ x,y ≤ L *)
H  = 2; (* -H ≤ z ≤ H *)
c1 = 0;
c2 = 0;
integralCurve = Graphics3D[Tube[Table[{0, -t, 0}, {t,0, L, L}], .07] ];
integralSurface = ContourPlot3D[F[u1[x,y,z], u2[x,y,z], c1, c2, θ] == 0, {x, -L,L}, {y, -L, L}, {z, -H,H}, Mesh -> False];
Show[integralSurface, integralCurve, AxesLabel ->{"x", "y", "z"}, BoxRatios -> Automatic]
, {{θ,2.2}, 0, π}]