Manipulate[
xr = 4π;
k = (Sqrt[1-V]); (* k is positive, or pure imaginary, or 0 *)
cka = Cos[k a]; (* cos(I x) = cosh(x) *)
ska = s[k, a]; (* ska = a if k = 0, sin(k a)/k if k > 0, or sinh(q a)/q if k = I q*)
A = ((ska-(k^2) ska)/(2 I cka+ska+(k^2) ska));
B = ((2 (cka-I ska))/(2 cka-I (1+(k^2)) ska));
CC = ((2 I cka+2 (k^2) ska)/(2 cka-I (1+(k^2)) ska)); (* C and D are protected symbols *)
DD = (2/(2 cka-I (1+(k^2)) ska));
T = (4/(4 (cka^2)+ (((1+(k^2)))^2)(ska^2))); (*Transmission coefficient, T = ((Abs[DD])^2) *)
ψ[x_] = Which[x< 0, (E^(I x)) + A (E^(-I x)), x < a,B Cos[k x] + CC s[k, x], True, DD (E^(I(x-a)))];
Plot[{Re[(E^(-I t)) ψ[x]], Abs[ψ[x]], -Abs[ψ[x]]}, {x, -2π, xr}, PlotStyle -> {Blue, {Black, Dotted}, {Black, Dotted}}, PlotRange ->{-2.5, 2.5}, 
AspectRatio -> Automatic, Ticks ->{{-2π, -π, π, 2π, 3π, 4π}, {-2, 1,2}},
AxesLabel -> {"(Subscript[k, o])x", "Re(Ψ)-blue, |Ψ|-dotted, E-green, V-red"},Prolog -> {Green, Line[{{-2 π, 1}, {xr, 1}}],
Red,Line[{{-2π, 0}, {0,0}, {0, V}, {a,V}, {a,0}, {xr, 0}}], 
Black,Text["T = "<> ToString@Re@N[T], {3π,2.5},{-1,1}]}]
,{{V, .75, ((Subscript[V, o])/("E"))}, -2, 2, Appearance -> "Labeled"},{{a, 2π, "(Subscript[k, o])a"}, 0, 3π, Appearance -> "Labeled"}, {{t, 0, "ωt"}, 0, 2π, ControlType -> Animator}, FrameMargins -> None, Initialization :> {s[k_, x_] := If[k == 0, x, Sin[k x]/k]}]